Ejercicios con estructura repetitiva Repetir_Hasta en Pseint – parte 3

Ejercicio 3.1: Suma de Números Pares e Impares

Diseña un algoritmo que pida al usuario ingresar números enteros uno por uno hasta que ingrese cero. Luego, muestra la suma de los números pares y la suma de los números impares utilizando la estructura “repetir_hastaque”.

Peudocódigo

				
					Proceso SumaNumerosParesImpares
	Definir numero, sumaPares, sumaImpares como Entero
	sumaPares <- 0
	sumaImpares <- 0
	
	Repetir
		Escribir "Ingrese un número entero (ingrese 0 para terminar): "
		Leer numero
		Si numero <> 0 Entonces
			Si numero % 2 = 0 Entonces
				sumaPares <- sumaPares + numero
			Sino
				sumaImpares <- sumaImpares + numero
			FinSi
		FinSi
	Hasta Que numero = 0
	
	Escribir "La suma de los números pares es: ", sumaPares
	Escribir "La suma de los números impares es: ", sumaImpares
FinProceso
				
			

Ejercicio 3.2: Números Primos

Diseña un algoritmo que solicite al usuario ingresar un número entero positivo y determine si es un número primo o no. Un número primo es aquel que solo es divisible por 1 y por sí mismo.

Peudocódigo

				
					Proceso NumerosPrimos
	Definir numero, i, contador como Entero
	contador <- 0
	
	Repetir
		Escribir "Ingrese un número entero positivo mayor que 1: "
		Leer numero
	Hasta Que numero > 1
	
	i <- 1
	Repetir
		Si numero % i = 0 Entonces
			contador <- contador + 1
		FinSi
		i <- i + 1
	Hasta Que i > numero
	
	Si contador = 2 Entonces
		Escribir numero, " es un número primo."
	Sino
		Escribir numero, " no es un número primo."
	FinSi
FinProceso
				
			

Ejercicio 3.3: Suma de Fracciones

Diseña un algoritmo que solicite al usuario ingresar un número entero positivo “n” y luego calcule la suma de las primeras “n” fracciones utilizando la fórmula: 1/1 + 1/2 + 1/3 + … + 1/n.

Peudocódigo

				
					Proceso SumaDeFracciones
	Definir n, i como Entero
	Definir suma como Real
	Definir textoSalida como Caracter
	
	Repetir
		Escribir "Ingrese un número entero positivo: "
		Leer n
	Hasta Que n > 0
	
	suma <- 0
	i <- 1
	Repetir
		textoSalida <- textoSalida  + "1/" + ConvertirATexto(i)
		Si i < n Entonces
			textoSalida <- textoSalida + " + "
		FinSi
		
		suma <- suma + 1 / i
		i <- i + 1
	Hasta Que i > n
	
	Escribir "La suma de las primeras ", n, " fracciones es "
	Escribir textoSalida " = ", suma
FinProceso
				
			

Ejercicio 3.4: Generación de números primos

Diseña un algoritmo que genere y muestre los primeros N números primos, donde N es un número ingresado por el usuario.

Peudocódigo

				
					Proceso GenerarPrimos
	Definir N, contadorPrimos, numero, i, contadorDivisores como Entero
	
	Repetir
		Escribir "Ingrese la cantidad de números primos que desea generar: "
		Leer N
	Hasta Que N > 0
		
	contadorPrimos <- 0
	numero <- 2
	Escribir "Los primeros ", N, " números primos son:"
	
	Repetir
		contadorDivisores <- 0
		Para i <- 1 Hasta numero Hacer
			Si numero % i = 0 Entonces
				contadorDivisores <- contadorDivisores + 1
			FinSi
		FinPara
		
		Si contadorDivisores = 2 Entonces
			contadorPrimos <- contadorPrimos + 1
			Escribir numero
		FinSi
		
		numero <- numero + 1
		
	Hasta Que contadorPrimos >= N
	
FinProceso
				
			

Ejercicios con estructura repetitiva Repetir_Hasta en Pseint – parte 2

Ejercicio 2.1: Suma de Números

Diseña un algoritmo que pida al usuario ingresar números enteros positivos uno por uno hasta que ingrese un número negativo. Luego, muestra la suma de los números ingresados.

Peudocódigo

				
					Proceso SumaDeNumeros
	Definir numero, suma como Entero
	suma <- 0
	
	Repetir
		Escribir "Ingrese un número entero positivo (ingrese un número negativo para terminar): "
		Leer numero
		Si numero >= 0 Entonces
			suma <- suma + numero
		FinSi
	Hasta Que numero < 0
	
	Escribir "La suma de los números ingresados es:", suma
FinProceso
				
			

Ejercicio 2.2: Factorial

Diseña un algoritmo que solicite al usuario ingresar un número entero positivo y luego calcule su factorial utilizando la estructura “repetir_hastaque”.

Peudocódigo

				
					
Proceso Factorial
	Definir n, facto como Entero
	facto <- 1
	
	Repetir
		Escribir "Ingrese un número entero positivo: "
		Leer n
	Hasta Que n > 0
	
	Repetir
		facto <- facto * n
		n <- n - 1
	Hasta Que n <= 0
	
	Escribir "El factorial es:", facto
FinProceso
				
			

Ejercicio 2.3: Tabla de Multiplicar

Diseña un algoritmo que solicite al usuario ingresar un número y luego muestre su tabla de multiplicar desde 1 hasta 12 utilizando la estructura “repetir_hastaque”.

Peudocódigo

				
					Proceso TablaDeMultiplicar
	Definir numero, i como Entero
	
	Escribir "Ingrese un número: "
	Leer numero
	i <- 1
	
	Repetir
		resultado <- numero * i
		Escribir numero, " x ", i, " = ", resultado
		i <- i + 1
	Hasta Que i > 12
FinProceso
				
			

Ejercicio 2.4: Adivinar el Número

Diseña un algoritmo que genere un número aleatorio entre 1 y 100 y permita al usuario adivinar el número. Utiliza la estructura “repetir_hastaque” hasta que el usuario adivine correctamente. Muestra el número de intentos necesarios para adivinarlo.

Peudocódigo

				
					Proceso AdivinarNumero
	Definir random, adivinanza, intentos como Entero
	random <- Aleatorio(1, 100)
	intentos <- 0
	
	Repetir
		Escribir "Adivina el número (entre 1 y 100): "
		Leer adivinanza
		intentos <- intentos + 1
		
		Si adivinanza < random Entonces
			Escribir "El número es mayor."
		Sino Si adivinanza > random Entonces
				Escribir "El número es menor."
			Sino
				Escribir "¡Correcto! Has adivinado el número en ", intentos, " intentos."
			FinSi
		FinSi
	Hasta Que adivinanza = random
FinProceso
				
			

Explicación

Este programa genera un número aleatorio entre 1 y 100 y luego permite al usuario adivinar el número. El programa brinda pistas al usuario diciendo si el número a adivinar es mayor o menor que el número propuesto por el usuario. El juego continúa hasta que el usuario adivina correctamente el número aleatorio, momento en el que se muestra la cantidad de intentos que le llevó al usuario adivinarlo.

Variables utilizadas:

  • random: Almacena el número aleatorio generado entre 1 y 100.
  • adivinanza: Almacena el número propuesto por el usuario en su intento de adivinanza.
  • intentos: Lleva un registro de la cantidad de intentos que ha realizado el usuario.

Pasos del Proceso:

  1. Se genera un número aleatorio random utilizando la función Aleatorio(1, 100). Este número es desconocido para el usuario y es el que debe adivinar.
  2. Se inicia la variable intentos en 0 para llevar un registro de la cantidad de intentos del usuario.
  3. Se entra en un bucle “repetir” que se ejecuta mientras adivinanza sea diferente de random, es decir, hasta que el usuario adivine el número correcto.
  4. Dentro del bucle, el programa solicita al usuario que ingrese su suposición mediante la línea Escribir "Adivina el número (entre 1 y 100): " y luego lee la suposición del usuario en la variable adivinanza.
  5. Se incrementa el contador de intentos en 1 para llevar un registro de los intentos realizados por el usuario.
  6. Luego, el programa compara la suposición del usuario adivinanza con el número aleatorio random.
  7. Si adivinanza es menor que random, el programa muestra “El número es mayor.”
  8. Si adivinanza es mayor que random, el programa muestra “El número es menor.”
  9. Si adivinanza es igual a random, significa que el usuario adivinó el número correcto, por lo que muestra “¡Correcto! Has adivinado el número en intentos intentos.” y termina el bucle.
  10. Una vez que el usuario adivina el número, el programa muestra la cantidad total de intentos que tomó adivinarlo.